OUTPUT_FORMAT(coff-h8300)
OUTPUT_ARCH(h8300h)
ENTRY("_start")
MEMORY
{
	vectors :	o = 0x000000, l = 0x100
	rom :		o = 0x000100, l = 0x20000
	ram :		o = 0xffdf10, l = 0x1ff0
	hsram :		o = 0xffff00, l = 0				/* high speed ram */
	stack :		o = 0xffff00, l = 0x4			/* 0x20000 - 0x3ffff */
	perireg :	o = 0xffff20, l = 0xe0
}
SECTIONS                                
{   
.perireg : {
	*(.perireg)
	}  > perireg
.hsram : {
	*(.hsram)
	}  > hsram
.vectors : {
	/* Use something like this to place a specific function's address
	into the vector table. 
	SHORT(ABSOLUTE(_foobar)) */
	*(.vectors)
	}  > vectors
.text : {                                       
	*(.text)                                
	*(.rodata)                              
	*(.strings)
	_etext = . ; 
	}  > rom

.tors : {
		___ctors = . ;
		*(.ctors)
		___ctors_end = . ;
		___dtors = . ;
		*(.dtors)
		___dtors_end = . ;
		}  > ram

.data : {
		*(.data)
		*(.tiny)
		 _edata = . ; 
		}  > ram
.bss : {
		 _bss_start = . ;
		*(.bss)
		*(COMMON)
		 _end = . ;  
		}  >ram
.stack : {
		 _stack = . ; 
		*(.stack)
		}  > stack
}